Kit Elektronik Latihan Menyolder - Robadge#1 Flip-Flop

Bagi agan-agan yang baru mengenal elektronik dan ingin belajar, terutama latihan menyolder komponen dasar ke papan PCB. Bisa coba Soldering Kit Robadge#1, selain bisa sebagai sarana latihan menyolder, Kit ini juga bentuknya lucu dan berfungsi sebagai rangkaian Flip-Flop (lampu LED kedap-kedip) yang bisa agan-agan pasang jadi bross menyala dibaju.

Untuk mendapatkan Soldering Kit Robadge#1 bisa order di tokopedia.com/bluino.

Atau jika agan ingin order PCB saja dengan jumlah lebih banyak, bisa langsung order saja PCBnya di PCBWAY.COM, harganya lebih murah $5 bisa mendapatkan papan PCB 10 keping dengan kualitas PCB yang sangat bagus. Bisa order melalui link PCB Robadge#1 disini.

Gambar Rangkaian

Berikut gambar rangkaiannya seperti dibawah:

Daftar Komponen:

• 1x PCB Robadge#1
• 2x Transistor NPN BC527
• 2x LED 5mm
• 2x C 100uF/16V
• 2x R 100 ohm 1/4W
• 2x R 10K ohm 1/4W
• 1x Saklar SPDT SS12D00G3
• 1x Baterai Coin CR2032
• 1x Dudukan Baterai Coin CR2032
• 1x Pin Peniti besi

LANGKAH-LANGKAH PERAKITAN

Pasang Komponen

Lubang kaki komponen resistor didisain untuk ukuran 1/6W. Namun masih bisa menggunakan ukuran yang lebih besar 1/4W, caranya dengan menekuk salah satu sisi kaki resistor seperti terlihan digambar, kemudian memasukannya ke lubang kaki komponen di PCB.
Untuk pemasangan komponen lainnya mudah saja cukup dimasukan ke lubang kaki komponen di PCB mengikuti lambang/simbol pada papan PCB.

Perhatikan jangan sampai terbailik pemasangannya, untuk kaki komponen yang lebih panjang berarti Positif.

Menyolder Komponen

Setelah semua komponen terpasang pada PCB, balikan PCB tersebut kemudian solder satu persatu dari setiap kaki komponen. Gunakan tang pemotong untuk memotong sisa kaki komponen yang panjang.

Menyolder Dudukan Baterai

Pasangkan dudukan baterai pada bagian belakang PCB kemudian solder kedua kakinya pada bagian depan PCB.

Menyolder Pin Peniti

Gunakan tang untuk membantu memegang Pin peniti ketika disolder, supaya tidak melukai tangan karena panas. Ketika menyolder perlu menempelkan mata solder cukup lama supaya timah bisa menempel dengan PCB dan Pin peniti.

Memasang Baterai

Baterai yang digunakan adalah tipe Cr2032 3V yang biasa digunakan untuk jam. Ketika memasang baterai jangan sampai terbalik kutub positif (tandanya terdapat tulisan) berada diatas atau menghadap keluar.

Menuliskan Nama

Pada bagian bawah dari PCB terdapat area putih, agan bisa menuliskan nama agan sendiri atau tulisan yang agan inginkan menggunakan spidol permanen.

Menyalakan

Untuk meyalakannya pada bagian depan terdapat saklar, geser ke kanan posisi ON dan agan akan melihat lampu LED pada bagian mata robot kedip bergantian.

Read More

Upload Program Arduino Wireless Bluetooth

Hai agan-agan sekalian, dalam tutorial kali ini ane akan menunjukan bagaimana cara Arduino Uno kamu supaya bisa diprogram menggunakan HP Android tanpa kabel alias lewat bluetooth. Caranya sangat mudah sekali, mari kita mulai saja! :)

Tutorial ini disponsori oleh perusahaan jasa pembuatan PCB dari china PCBWAY dengan kualitas yang sangat bagus, semua produk Bluino Electronics menggunakan jasa percetakan PCBWAY.

Peralatan dan Komponen

• Arduino Uno
• Bluetooth HC-05 module
• Mini breadboard
• Capacitor 1uf/50v (elco)
• 5 pcs x Jumper wires Female to Male
• USB cable
• Android Smartphone
• Laptop/PC

Software:

• Arduino IDE
• Aplikasi Bluino Loader

Program Arduino Kamu menggunakan Laptop/Komputer

Salin kode yang ada pada kolom deskripsi dibawah ke jendela editor Arduino IDE, kemudian pada menu Tools pilih Board Arduino UNO, terakhir tekan icon Upload untuk mengisikan program ke board Arduino Uno.

#include <SoftwareSerial.h>

SoftwareSerial BTSerial(10, 11); // RX | TX

void setup(){
  pinMode(9, OUTPUT);     
  digitalWrite(9, HIGH);  // pin ini akan membuat kondisi HIGH pada HC-05 pin EN (key pin), merubah menjadi mode AT Command
  Serial.begin(9600);     // Baud rate antara komputer dengan Arduino Uno
  Serial.println("Enter AT commands:");
  BTSerial.begin(38400);  // Baud rate antara Arduino Uno dengan HC-05, mode AT Command
}

void loop(){
  
  // Arduino uno menunggu balasan peritah dari HC-05 kemudian meneruskan kirim data ke Arduino Serial Monitor
  if (BTSerial.available())
    Serial.write(BTSerial.read());

  // Arduino Uno menunggu perintah dari Arduino Serial Monitor kemudian meneruskan kirim data ke HC-05
  if (Serial.available())
    BTSerial.write(Serial.read());
}

Pada baris kode diatas berisikan program yang memfungsikan Arduino Uno sebagai jembatan penghubung komunikasi antara serial monitor pada software Arduino IDE dengan Bluetooth HC-05 (pada mode AT Command).

Langkah selanjutnya rangkai Arduino Uno dengan Bluetooth HC-05 seperti gambar dibawah, akan lebih mudah merangkainya menggunakan kabel jumper Dupont Male to Female.

Setelah selesai merangkai hubungkan Arduino IDE ke Laptop/Komputer, buka Serial Monitor pada software Arduino IDE dan pilih baud rate 9600.

Pastikan LED pada modul buletooth HC-05 berkedip dengan interval sekitar 2 detik yang menandakan HC-05 dalam mode AT Command dan siap menerima perintah untuk merubah parameter dari HC-05 tersebut. Pada Arduino IDE Serial Monitor ketik dan kirimkan perintah "AT" kemudian akan ada balasan "OK", ini tandanya rangkaian dan program yang kamu buat sudah benar.

Sekarang saatnya merubah beberapa parameter pada bluetooth HC-05 supaya nantinya dapat berfungsi untuk upload board Aruino Uno melalui wireless bluetooth. Parameter yang perlu kamu rubah adalah:

• AT+NAME=Bluino#01 (untuk merubah nama modul bluetooth, default "HC-05")
• AT+UART=115200,0,0 (untuk merubah baud rate menjadi 115200, default "9600")
• AT+POLAR=1,0 (untuk merubah kondisi pin STATE menjadi "HIGH/1", default "LOW/0")

Kamu juga dapat merubah parameter lain yang biasa diperlukan:

• AT+ORGL (untuk mengembalikan parameter HC-05 ke settingan default)
• AT+PSWD=0000 (untuk merubah code keamanan pairing, default "1234")
• AT+RESET (untuk keluar dari mode AT Command")

Pastikan dari setiap perintah yang dikirim mendapatkan respon/balasan "OK", atau kamu dapat memastikan kembali apakah parameternya sudah berubah dengan mengirimkan perintah AT Command tanpa diikuti nilai parameter contoh seperti "AT+NAME".

Upload Program ke Arduino Uno Melalui Bluetooth

Setelah selesai merubah beberapa parameter HC-05 di langkah sebelumnya. Modul Bluetooth HC-05 kamu sekarang sudah dapat dirangkaikan dengan Arduino Uno untuk bisa upload program secara wireless lewat bluetooth, ikuti rangkaian seperti dibawah:

Kamu dapat melakukan upload program ke Arduino Uno kamu melalui bluetooth dengan dua cara melalui Laptop/Komputer (Arduino IDE) atau menggunakan smartphone Android (Bluino Loader).
Jika kamu menggunakan Laptop/komputer, langkah pertama aktifkan perangkat bluetooth pada Laptop/komputer kemudian lakukan pairing dengan modul bluetooth HC-05, apabila kamu tidak merubah code security pairing kamu bisa memasukan kode defaultnya yaitu "1234".

Pada software Arduino IDE pilih menu tools pilih board Arduino Uno, ketika memilih port tujuan untuk program yang akan diupload, pilihlah port yang terhubung dengan modul bluetooth HC-05 yang sudah terpairing sebelumnya.

Read More

Membunyikan Buzzer

Membunyikan Buzzer

Buzzer merupakan komponen elektronik yang dapat menghasilkan bunyi, terdapat dua jenis buzzer yaitu buzzer aktif dan buzzer pasif. Buzzer jenis actif dapat memproduksi suara/getaran sendiri, kita cukup menghubungkannya dengan tegangan 5V dan buzzer tersebut mengeluarkan suara. Sedangkan buzzer pasif tidak dapat menghasilkan suara sendiri, kita harus memberikannya tegangan berbentuk gelombang dan mempunyai frekuensi maka buzzer pasif akan mengeluarkan suara. Speaker adalah salah satu contoh dari jenis buzzer aktif.
Pada latihan sekarng menggunakan buzzer jenis pasif untuk memainkan nada-nada sederhana.

Kebutuhan Komponen:

— 1 x Arduino UNO
— 1 x Buzzer

Komponen yang digunakan pada Shield:

1 x Buzzer yang dihubungkan ke pin A3.

Rangkaian:

Upload sketch:

Buka software Arduino IDE apabila menggunakan PC/Laptop. Jika menggunakan Android dapat membuka aplikasi Bluino Loader yang sudah diinstal dari Google Playstore. Buka sketch Latihan 08 yang sudah diunduh dan disimpan pada folder Examples sebelumnya.

Untuk membuka sketch temukan file di: BluinoLoader > examples > Belajar_Arduino_Dasar > Latihan_08

Cara lain dapat juga upload sketch langsung melalui aplikasi ini ke Arduino melalui USB OTG atau Bluetooth dengan cara menekan ikon upload (tanda panah ke kanan) dibawah.

/* Bluino Starter Shield
   Latihan 08 Membunyikan Buzzer

   This sketch uses the buzzer to play songs.
   The Arduino's tone() command will play notes of a given frequency.

   Version 1.0 9/2017 MK
*/


const int buzzerPin = A3;    // connect the buzzer to pin A3
const int songLength = 18;   // sets the number of notes of the song

// Notes is an array of text characters corresponding to the notes
// in your song. A space represents a rest (no tone)

char notes[songLength] = {
  'c', 'd', 'f', 'd', 'a', ' ', 'a', 'g', ' ', 'c', 'd', 'f', 'd', 'g', ' ', 'g', 'f', ' '};

// beats[] is an array of values for each note. A "1" represents a quarter-note,
// "2" a half-note, and "4" a quarter-note.
// Don't forget that the rests (spaces) need a length as well.

int beats[songLength] = {
  1, 1, 1, 1, 1, 1, 4, 4, 2, 1, 1, 1, 1, 1, 1, 4, 4, 2};

int tempo = 113;  // The tempo is how fast to play the song (beats per second).

void setup() {
  pinMode(buzzerPin, OUTPUT);  // sets the  buzzer pin as an OUTPUT
}


void loop() {
  int i, duration; //

  for (i = 0; i < songLength; i++) {  // for loop is used to index through the arrays
    duration = beats[i] * tempo;  // length of note/rest in ms

    if (notes[i] == ' ')          // is this a rest?
      delay(duration);            // then pause for a moment
    else {                        // otherwise, play the note
      tone(buzzerPin, frequency(notes[i]), duration);
      delay(duration);            // wait for tone to finish
    }
    delay(tempo/10);              // brief pause between notes
  }

}

int frequency(char note) {
  int i;
  const int numNotes = 8;  // number of notes we're storing
  char names[numNotes] = {
    'c', 'd', 'e', 'f', 'g', 'a', 'b', 'C'    };
  int frequencies[numNotes] = {
    262, 294, 330, 349, 392, 440, 494, 523    };

  // Now we'll search through the letters in the array, and if
  // we find it, we'll return the frequency for that note.

  for (i = 0; i < numNotes; i++) { // Step through the notes
    if (names[i] == note) {        // Is this the one?
      return(frequencies[i]);     // Yes! Return the frequency and exit function.
    }
  }
  return(0);  // We looked through everything and didn't find it,
  // but we still need to return a value, so return 0.
}

Catatan kode:

char notes[] = "cdfda ag cdfdg gf ";

char names[] = {'c','d','e','f','g','a','b','C'};

Sampai saat ini kita banyak berlatih dengan data numerik, tapi Arduino juga dapat mengolah data text. Satu huruf dari sebuah text disebut "char" (cahracter). Ketika text atau gabungan dari banyak character dituliskan dalam kode Arduino dapat dituliskan menggunakan tanda kutip dua (juga disebut "string").

tone(pin, frequency, duration);

Banyak fungsi-fungsi bawaan bahasa arduino yang sangat berguna salah satunya fungsi untuk mengendalikan buzzer adalah fungsi tone(). Fungsi ini akan mengelhasilkan frekuensi tertentu pada pin output, memjadikan fungsi ini sangat berguna untuk membunyikan sebuah buzzer atau speaker. Jika kamu memberi nilai untuk durasi (dalm milidetik), maka nada akan berbunyi dan kemudian berhenti. Jika tidak diberikan nilai durasi maka nada akan berbunyi terus menerus, namun kamu masih dapat menghentikannya menggunkan fungsi noTone().

Apa yang seharusnya kamu lihat:

Kamu akan mendengar musik yang keluar dari buzzer. Jika ini tidak bekerja, periksa apakah lubang suara pada buzzer tertutup dan pastikan sketch sudah masuk kedalam Arduino. 

Read More

Mengendalikan Relay

Mengendalikan Relay

Relay pada dasarnya merupakan sebuah saklar mekanik yang dikontrol secara listrik. Didalam relay terdapat lilitan dengan inti besi yang akan berubah menjadi magnet ketika dialiri arus listrik dan menarik tuas saklar sehingga menyebabkan saklar menjadi kontak. Pada latihan ini akan belajar bagaimana cara menontrol relay menggunakan Arduino.

Kebutuhan Komponen:

— 1 x Arduino UNO
— 1 x Relay 5V (SPDT)
— 2 x LED
— 1 x Transistor NPN
— 1 x Dioda 1N4148
— 2 x Resistor 330Ω
— 1 x Resistor 10kΩ
— 1 x Breadboard mini

Komponen yang digunakan pada Shield:

1 x Relay yang terhubung ke D12.

Rangkaian:

Upload sketch:

Buka software Arduino IDE apabila menggunakan PC/Laptop. Jika menggunakan Android dapat membuka aplikasi Bluino Loader yang sudah diinstal dari Google Playstore. Buka sketch Latihan 10 yang sudah diunduh dan disimpan pada folder Examples sebelumnya.

Untuk membuka sketch temukan file di: BluinoLoader > examples > Belajar_Arduino_Dasar > Latihan_10

Cara lain dapat juga upload sketch langsung melalui aplikasi ini ke Arduino melalui USB OTG atau Bluetooth dengan cara menekan ikon upload (tanda panah ke kanan) dibawah.

/* Bluino Starter Shield
   Latihan 10 Mengendalikan Relay

   A relay is a electrically-controlled mechanical switch. It has an
   electro-magnetic coil that either opens or closes a switch.

   Version 1.0 9/2017 MK
*/


const int relayPin = 12;     // This pin drives the transistor (which drives the relay)
const int timeDelay = 1000;  // delay in ms for on and off phases

// You can make timeDelay shorter, but note that relays, being
// mechanical devices, will wear out quickly if you try to drive them too fast.


void setup() {
  pinMode(relayPin, OUTPUT);  // set pin as an output
}


void loop() {
  digitalWrite(relayPin, HIGH);  // turn the relay on
  delay(timeDelay);              // wait for one second
  digitalWrite(relayPin, LOW);   // turn the relay off
  delay(timeDelay);              // wait for one second
}

Catatan kode:

digitalWrite(relayPin, HIGH);

Ketika transistor sebagai switching aktif, akan mengaktifkan lilitan relay dan kontak pada relay terhubung, ini akan menghubungkan pin relay COM dengan NO (Normally Open). Pada latihian ini menggunakan kedua pin ini sebagai saklar LED tapi kamu bisa menggunakan untuk perangkat elektronik lain bertegagngan tinggi (220AC) seperti lampu pijar, motor dll disesuaikan dengan kemampuan relay tersebut.

digitalWrite(relayPin, LOW);

Relay mempunyai pin NC (Normally Close), Pin NC kebalikan dari pin NO yaitu akan terhubung antara pin COM dengan NC ketika kondisi relay mati. Pin-pin kontak pada relay dapat digunakan sesuai dengan kebutuhan apakah dalam keadaan aktif nyala atau mati. Kedua pin NO dan NC juga dapat digunakan untuk dua peralatan yang nyalanya bergantian.

Apa yang seharusnya kamu lihat:

Kamu seharusnya dapat mendengarkan suara klik ketika kontak relay aktif, dan melihat kedua LED menyala bergantian dengan interval waktu masing-masing 1 detik. Jika tidak terjadi, pastikan kedua LED terangkai benar dengan pin kontak relay dan pastikan sketch sudah masuk kedalam Arduino. 

Read More

7-Segment

7-Segment

Pada latihan ini akan belajar bagaimana menampilkan data/angka pada 7-segment. Rangkaian dan library yang digunakan pada latihan ini mengacu pada Digit Shield. Untuk bisa menampilkan angka pada 7-segment memerlukan komponen IC 74LS595 (Shift Register) dan IC 74LS247 (BCD to 7-segment).

Pada pemogramannya menggunakan beberapa fungsi khusus yang sudah dibuat menjadi library, seperti fungsi DigitShield.begin() digunakan pada awal inisialisasi, fungsi DigitShield.setvalue(value) digunakan untuk menampilkan angka pada 7-segment bisa berupa nilai hasil pembacaan sensor, jam pembacaan dari modul RTC, dll.

Kebutuhan Komponen:

— 1 x Arduino UNO
— 1 x 4 7-segment
— 1 x IC 74LS595
— 1 x IC 74LS247
— 8 x Resistor 100Ω
— 4 x Resistor 10kΩ

Komponen yang digunakan pada Shield:

1 x 4x7-segment yang terhubung ke D5, D6, D7 & D8.

Rangkaian:

Upload sketch:

Buka software Arduino IDE apabila menggunakan PC/Laptop. Jika menggunakan Android dapat membuka aplikasi Bluino Loader yang sudah diinstal dari Google Playstore. Buka sketch Latihan 11 yang sudah diunduh dan disimpan pada folder Examples sebelumnya.

Untuk membuka sketch temukan file di: BluinoLoader > examples > Belajar_Arduino_Dasar > Latihan_11

Cara lain dapat juga upload sketch langsung melalui aplikasi ini ke Arduino melalui USB OTG atau Bluetooth dengan cara menekan ikon upload (tanda panah ke kanan) dibawah.

/* Bluino Starter Shield
  Latihan 11 7-segment

  To display number counter-up 0 - 9999 on sevent segment.

  Version 1.0 9/2017 MK
*/


#include <digitshield.h>




int counter = 0;

// Create a Digit Shield connected to Arduino pins 5,6,7,8
// Connected to pins 5,6,7,8 on the shield, respectively.
DigitShieldClass digitShield(5, 6, 7, 8);

void setup() {
  DigitShield.begin();      // Initialize the Digit Shield. This is required before use.
}

void loop() {
  digitShield.setValue(counter);    // Set an integer value to display
  counter = counter + 1;    // Counter-up added 1
  delay(300);               // Delay time when increasing counter
  if (counter >= 9999) {    // Reset counter to 0 if reach 10000
    counter = 0;
  }
}

Catatan kode:

#include <digitshield.h>

Kode berikut memberitahu Arduino untuk meyertakan library DigitShield. Tanpa menggunakan library ini, nanti semua fungsi yang berhubungan dengan 7-segment tidak akan dikenali, maka pastikan kamu sudah mendownload library tersebut dan menyimpannya pada subfolder libraries serta pada awal baris kode menyertakannya.

digitShield.setValue(counter);

Fungsi ini akan menampilkan angka pada 7-segment, data yang dapat ditampilakan dapat berupa integer atau double (bilangan desimal mempunyai angka dibelakang koma).

Apa yang seharusnya kamu lihat:

Kamu akan melihat nilai pada 7-segment mencacah naik dari 0 sampai 9999, dengan jeda waktu 300 ms tiap perbuahan angkanya sesuai dengan delay. Jika tidak tampil, pastikan sketch sudah masuk kedalam Arduino. 

Read More

Mengendalikan Motor Servo

Mengendalikan Motor Servo

Motor servo sangat cocok pengaplikasiannya dalam pembuatan project robotik karena motor servo bisa melakukan yang tidak bisa dilakukan oleh motor biasa yaitu dapat berputar pada posisi yang akurat. Dengan memberikan variasi lebar pulsa dari tegangan output arduino ke servo, sebagai contoh lebar pulsa 1.5ms akan menyebabkan servo bergerak pada posisi 90 derajat. Pada latihan ini kamu akan belajar menggunakan PWM (pulse width modulation) untuk mengontrol dan memutarkan sebuah servo.

Kebutuhan Komponen:

— 1 x Arduino UNO
— 1 x Servo

Komponen yang digunakan pada Shield:

1 x Servo yang dihubungkan ke pin D3.

Rangkaian:

Upload sketch:

Buka software Arduino IDE apabila menggunakan PC/Laptop. Jika menggunakan Android dapat membuka aplikasi Bluino Loader yang sudah diinstal dari Google Playstore. Buka sketch Latihan 09 yang sudah diunduh dan disimpan pada folder Examples sebelumnya.

Untuk membuka sketch temukan file di: BluinoLoader > examples > Belajar_Arduino_Dasar > Latihan_09

Cara lain dapat juga upload sketch langsung melalui aplikasi ini ke Arduino melalui USB OTG atau Bluetooth dengan cara menekan ikon upload (tanda panah ke kanan) dibawah.

/* Bluino Starter Shield
   Latihan 09 Mengendalikan Motor Servo

   Sweep a servo back and forth through its full range of motion.

   Version 1.0 9/2017 MK
*/


#include <Servo.h>  // servo library

Servo servo1;  // servo control object


void setup() {
  servo1.attach(3);  //Connect the servo to pin 3
}


void loop() {
  int position;

  // Change position at full speed:
  servo1.write(90);    // Tell servo to go to 90 degrees
  delay(1000);         // Pause to get it time to move
  servo1.write(180);   // Tell servo to go to 180 degrees
  delay(1000);         // Pause to get it time to move
  servo1.write(0);     // Tell servo to go to 0 degrees
  delay(1000);         // Pause to get it time to move


  // Tell servo to go to 180 degrees, stepping by two degrees each step
  for(position = 0; position < 180; position += 2) {
    servo1.write(position);  // Move to next position
    delay(20);               // Short pause to allow it to move
  }

  // Tell servo to go to 0 degrees, stepping by one degree each step
  for(position = 180; position >= 0; position -= 1) {
    servo1.write(position);  // Move to next position
    delay(20);               // Short pause to allow it to move
  }
}

Catatan kode:

#include <Servo.h>

#include adalah sebuah perintah "preprocessor" spesial untuk menyertakan sebuah library (atau file lain) kedalam sketch.

Servo servo1;
servo1.attach(3);

Pada library servo menambahkan beberapa perintah untuk dapat mengontrol sebuah servo. Sebagai persiapan supaya Arduino dapat mengontrol sebuah servo, terlebih dahulu kamu harus membuat "object" servo untuk setiap servo (dalam contoh ini object diberi nama ("servo1"), kemudian tuliskan perintah "attach" untuk menghubungkan ke pin digital (dalam contoh ini menggunakan pin 3).

servo1.write(180);

Servo yang digunakan pada latihan ini tidak dapat berputar 360 derajat, tapi dapat diberi perintah untuk bergerak pada posisi tertentu. Kita menggunakan fungsi pada library servo, perintah write() akan membuat servo bergerak pada nilai derajat tertentu (0 sampai 180). Perlu diingat bahwa servo memerlukan waktu untuk bergerak dari satu posisi ke posisi lain, maka tambahkan delay() apabila diperlukan.

Apa yang seharusnya kamu lihat:

Kamu akan melihat servo bergerak ke beberapa posisi pada kecepatan tertentu. Jika motor servo tidak bergerak, periksa kembali koneksi kabel dan pastikan sketch sudah masuk kedalam Arduino. 

Read More

LED Berjalan

LED Berjalan

Kamu telah menyelesaikan LED berkedip menyala dan mati. Sekarang saatnya untuk mencoba latihan yang sedikit lebih rumit yaitu dengan menghubunkan empat LED sekaligus. Latihan ini bagus untuk melatih dalam memahami program dan bagaimana program tersebut berjalan didalam Arduino.

Untuk mengendalikan beberapa LED, kamu akan belajar beberapa trik pemograman supaya kode kamu terlihat lebih sederhana:
for() loops - digunakan ketika ingin membuat sebuah fungsi berjalan beberapa kali.

arrays[ ] - digunakan untuk mtengatur beberapa parameter dengan mudah dengan mengelompokannya bersama.

Kebutuhan komponen:

— 1 x Arduino UNO
— 4 x LED
— 4 x 330 Ohm Resistor

Komponen yang digunakan pada Shield:

4 x yang terhubung ke pin D9, D10, D11 & D13.
Selector switch pada posisi LED.

Rangkaian:

Upload sketch:

Buka software Arduino IDE apabila menggunakan PC/Laptop. Jika menggunakan Android dapat membuka aplikasi Bluino Loader yang sudah diinstal dari Google Playstore. Buka sketch Latihan 04 yang sudah diunduh dan disimpan pada folder Examples sebelumnya.

Untuk membuka sketch temukan file di: BluinoLoader > examples > Belajar_Arduino_Dasar > Latihan_04

Cara lain dapat juga upload sketch langsung melalui aplikasi ini ke Arduino melalui USB OTG atau Bluetooth dengan cara menekan ikon upload (tanda panah ke kanan) dibawah.

/* Bluino Starter Shield
  Latihan 04 LED Berjalan
   
  It turns each LED ON and then OFF before going to the next LED.

  Version 1.0 9/2017 MK
*/

int ledPins[] = {9,10,11,13};   // Defines an array to store the pin numbers of the 4 LEDs.
// An array is like a list variable that can store multiple numbers.
// Arrays are referenced or "indexed" with a number in the brackets [ ]. See the examples in
// the pinMode() functions below. 

void setup() {
  // setup all 4 pins as OUTPUT - notice that the list is "indexed" with a base of 0.
  pinMode(ledPins[0],OUTPUT);  // ledPins[0] = 9
  pinMode(ledPins[1],OUTPUT);  // ledPins[1] = 10
  pinMode(ledPins[2],OUTPUT);  // ledPins[2] = 11
  pinMode(ledPins[3],OUTPUT);  // ledPins[3] = 13
}

void loop() {
  int index;
  int delayTime = 300; // milliseconds to pause between LEDs
   
  for(index = 0; index <= 3; index++) {  // step through the LEDs, from 0 to 3
    digitalWrite(ledPins[index], HIGH);  // turn LED on
    delay(delayTime);                    // pause to slow down
    digitalWrite(ledPins[index], LOW);   // turn LED off
  }
}

Catatan kode:

int ledPins[] = {9,10,11,13};

Ketika harus mengatur variabel yang cukup banyak, dapat menggunakan "array" sebagai cara untuk mengelopokan variabel sehingga menjadi lebih mudah. Pada contoh latihan kali ini kita membuat sebuah array dari integer, diberi nama ledPins dengan empat elemen.

digitalWrite(ledPins[0], HIGH);

Disini untuk menggunakan ledPins kamu dapat mengacu pada elemen dalam array berdasarkan posisinya. Elemen pertama ada pada posisi 0, yang kedua ada di posisi 1, dan seterusnya. Untuk mengacu pada tiap elemen yang menggunakan "ledPins[x]" di mana x adalah posisinya. Di sini kita membuat pin digital 9 HIGH, karena elemen array pada posisi 0 adalah "9".

for(index = 0; index <= 3; index++)

Didalam sketch, menggunakan for() loop untuk membuat nyala LED berpindah satu persatu dari pin D9 sampai D13.

Setiap for() loop mempunyai tiga parameter dan dipisahkan menggunakan titik koma (;):

1. index = 0; Sesuatu yang dikerjakan sebelum dimulai: Membuat index = 0.
2. index <= 3; Operasi logika yang dites, selama hasilnya benar (true) akan terus looping: Jika index lebih kecil atau sama dengan 3, akan menjalankan kode yang ada didalam tanda kurung {}. Ketika index = 4, akan keluar dari loop dan melanjutkan baris kode selanjutnya didalam sketch.
3. index++ Sesuatu yang dilakukan setelah menjalankan satu baris loop: Meletakan "++" setelah sebuah variabel bermaksud menambahkan variabel tersebut dengan satu. Dapat juga menggunakan "index = index + 1".

Apa yang seharusnya kamu lihat:

Kamu akan melihat nyala lampu LED bergerak satu arah seperti berjalan. Jika ini tidak terjadi, pastikan sketch sudah masuk kedalam Arduino. 

Read More

Push Button

Push Button

Sampai saat ini kebanyakan fokus latihan pada komponen output. Sekarang kita mencoba latihan menggunakan komponen input sederhana yang umum digunakan yaitu push button menggunakan fungsi digital input. Push button dirangkaikan dengan Arduino sehingga ketika push button ditekan akan menjadikan kondisi LOW.

Pada latihan ini, menggunakan parameter INPUT_PULLUP didalam fungsi pinMode(), sehingga tidak memerlukan resistor yang dihubungkan sebagai pull-up untuk menjaga inputan pada pin dalam kondisi HIGH ketika push button tidak ditekan.

Kebutuhan Komponen:

— 1 x Arduino UNO
— 2 x Push Button
— 1 x LED
— 1 x Resistor 330Ω

Komponen yang digunakan pada Shield:

2 x Push Button yang terhubung dengan D2 & D4.
1 x LED yang terhubung ke D13.

Rangkaian:

Upload sketch:

Buka software Arduino IDE apabila menggunakan PC/Laptop. Jika menggunakan Android dapat membuka aplikasi Bluino Loader yang sudah diinstal dari Google Playstore. Buka sketch Latihan 05 yang sudah diunduh dan disimpan pada folder Examples sebelumnya.

Untuk membuka sketch temukan file di: BluinoLoader > examples > Belajar_Arduino_Dasar > Latihan_05

Cara lain dapat juga upload sketch langsung melalui aplikasi ini ke Arduino melalui USB OTG atau Bluetooth dengan cara menekan ikon upload (tanda panah ke kanan) dibawah.

/* Bluino Starter Shield
   Latihan 05 Push Button

   Use pushbuttons for digital input.

   Version 1.0 9/2017 MK
*/

const int button1Pin = 2;  // pushbutton 1 pin
const int button2Pin = 4;  // pushbutton 2 pin
const int ledPin =  13;    // LED pin

int button1State, button2State;  // variables to hold the pushbutton states


void setup() {
  // Set up the pushbutton pins to be an input with the internal pull-up resistor enabled :
  pinMode(button1Pin, INPUT_PULLUP);
  pinMode(button2Pin, INPUT_PULLUP);
  pinMode(ledPin, OUTPUT); // Set up the LED pin to be an output
  
}

void loop() {
  button1State = digitalRead(button1Pin);
  button2State = digitalRead(button2Pin);

  // if button1 or button 2 are pressed (but not both)
  if (((button1State == LOW) && (button2State == HIGH)) || ((button1State == HIGH) && (button2State == LOW))) {
    digitalWrite(ledPin, HIGH);  // turn the LED on
  }
  else {
    digitalWrite(ledPin, LOW);  // turn the LED off
  }
}

Catatan kode:

pinMode(button2Pin, INPUT_PULLUP);

Semua pin pada Arduino dapat difungsikan sebagai input sebagaimana bisa difungsikan sebagai output. Sebelumnya harus dinyatakan terlebih dahulu pin mana yang akan diset sebagai input dengan menggunakan fungsi pinMode(). Pada fungsi pinMode() menggunakan parameter INPUT_PULLUP bertujuan untuk mengaktifkan internal pull-up resistor didalam IC mikrokontroller secara kode.

button1State = digitalRead(button1Pin);

Untuk membaca sebuah inputan digital menggunakan fungsi digitalRead(). Fungsi ini akan menghasilkan HIGH jika tegangan 5V terhubung dengan pin, atau LOW jika tegangan 0V terhubung dengan pin.

if (button1State == LOW)

Karena menghubungkan salah satu kaki push button ke GND, maka akan membaca LOW ketika push button ditekan. Disini menggunakan operator dua sama dengan ("==") untuk mendeteksi apakah push button ditekan.

Apa yang seharusnya kamu lihat:

Kamu akan melihat LED akan menyala ketika salah satu push button ditekan, dan akan mati ketika kedua push button ditekan. (Lihat pada sketch kenapa bisa terjadi seperti itu!). Jika tidak bekerja, pastikan sketch sudah masuk kedalam Arduino. 

Read More

Membaca Sensor Cahaya

Membaca Sensor Cahaya

Pada latiahan 02 telah belajar menggunakan potensiometer, merupakan hambatan yang dapat berubah tergantung dari posisi putaran knob. Pada latihan sekarang akan menggunakan sebuah sensor cahaya (photoresistor), dimana nilai hambatan akan berubah-ubah bergantung dari intensitas cahaya yang diterima oleh sensor. Kita memerlukan rangkaian pembagi tegangan untuk bisa menggunakan photoresistor supaya perubahan hambatannya dapat menyebabkan perubahan tegangan dan dapat dibaca oleh Arduino.

Kebutuhan Komponen:

— 1 x Arduino UNO
— 1 x Photoresistor
— 1 x LED
— 1 x Resistor 10kΩ
— 1 x Resistor 330Ω

Komponen yang digunakan pada Shield:

1 x Photoresistor yang terhubung ke A1.
1 x LED yang terhubung ke D9.

Rangkaian:

Upload sketch:

Buka software Arduino IDE apabila menggunakan PC/Laptop. Jika menggunakan Android dapat membuka aplikasi Bluino Loader yang sudah diinstal dari Google Playstore. Buka sketch Latihan 06 yang sudah diunduh dan disimpan pada folder Examples sebelumnya.

Untuk membuka sketch temukan file di: BluinoLoader > examples > Belajar_Arduino_Dasar > Latihan_06

Cara lain dapat juga upload sketch langsung melalui aplikasi ini ke Arduino melalui USB OTG atau Bluetooth dengan cara menekan ikon upload (tanda panah ke kanan) dibawah.

/* Bluino Starter Shield
   Latihan 06 Membaca Sensor Cahaya

   Use a photoresistor (light sensor) to control the brightnessof a LED.

   Version 1.0 9/2017 MK
*/

const int sensorPin = A1;
const int ledPin = 9;


int lightLevel;  // We'll also set up some global variables for the light level
int calibratedlightLevel; // used to store the scaled / calibrated lightLevel

void setup() {
  pinMode(ledPin, OUTPUT);    // Set up the LED pin to be an output.
}

void loop() {
  lightLevel = analogRead(sensorPin);  // reads the voltage on the sensorPin

  calibratedlightLevel = map(lightLevel, 0, 1023, 0, 255);  // scale the lightLevel from 0 - 1023 range to 0 - 255 range.
                                                  // the map() function applies a linear scale / offset.
                                                  // map(inputValue, fromMin, fromMax, toMin, toMax);

  analogWrite(ledPin, calibratedlightLevel);    // set the led level based on the input lightLevel.
}

Catatan kode:

calibratedlightLevel = map(lightLevel, 0, 1023, 0, 255);

Parameters

map(value, fromLow, fromHigh, toLow, toHigh)

value: nilai yang dipetakan

fromLow: batas bawah dari range nilai terbaca

fromHigh: batas atas dari range nilai terbaca

toLow: batas bawah dari range nilai diinginkan

toHigh: batas atas dari range nilai diinginkan

Ketika membaca sinyal analog menggunakan fungsi analogRead(), akan terbaca nilai dari angka 0 sampai 1023. Tapi jika kita ingin mengeluarkan output pada pin PWM menggunakan fungsi analogWrite(), nilai yang diset antara 0 sampai 255. Kita dapan memperkecil nilai yang mempunyai range besar menjadi range yang kecil atau sebaliknya menggunakan fungsi map().

Apa yang seharusnya kamu lihat:

Kamu akan melihat LED menyala lebih terang atau lebih redup tergantung dari intensitas cahaya yang terbaca oleh photoresistor. Jika tidak terjadi, pastikan sketch sudah masuk kedalam Arduino. 

Read More

Membaca Sensor Suhu

Membaca Sensor Suhu

Sensor suhu berfungsi untuk mengukur suhu lingkungan sekitar. Sensor yang digunakan pada latihan ini adalah TMP36 memiliki tiga pin; positif, ground dan sinyal. Ini merupakan jenis sensor suhu yang linier, setiap perubahan suhu satu derajat sama dengan perubahan 10 mV pada keluaran sensor.

Sensor TMP36 memiliki nilai 750 mV pada suhu 25°C (suhu ruangan). Pada latihan ini akan mempelajari bagaimana menggunakan sensor suhu dengan Arduino, dan menggunakan serial monitor untuk menampilkan suhu.

Kebutuhan Komponen:

— 1 x Arduino UNO
— 1 x Sensor suhu

Komponen yang digunakan pada Shield:

1 x Sensor suhu yang terhubung ke pin A2.

Rangkaian:

Upload sketch:

Buka software Arduino IDE apabila menggunakan PC/Laptop. Jika menggunakan Android dapat membuka aplikasi Bluino Loader yang sudah diinstal dari Google Playstore. Buka sketch Latihan 07 yang sudah diunduh dan disimpan pada folder Examples sebelumnya.

Untuk membuka sketch temukan file di: BluinoLoader > examples > Belajar_Arduino_Dasar > Latihan_07

Cara lain dapat juga upload sketch langsung melalui aplikasi ini ke Arduino melalui USB OTG atau Bluetooth dengan cara menekan ikon upload (tanda panah ke kanan) dibawah.

/* Bluino Starter Shield
   Latihan 07 Membaca Sensor Suhu

   Use the "serial monitor" window to read a temperature sensor.

   Version 1.0 9/2017 MK
*/



const int temperaturePin = A2;  // We'll use analog input A2 to measure the temperature sensor's signal pin.


void setup() {
    Serial.begin(115200); //Initialize serial port & set baud rate to 115200 bits per second (bps)
}


void loop() {
    float voltage, degreesC, degreesF; //Declare 3 floating point variables

    voltage = getVoltage(temperaturePin); //Measure the voltage at the analog pin

    degreesC = (voltage - 0.5) * 100.0; // Convert the voltage to degrees Celsius

    degreesF = degreesC * (9.0 / 5.0) + 32.0; //Convert degrees Celsius to Fahrenheit

    //Now print to the Serial monitor. Remember the baud must be 115200 on your monitor!
    // These statements will print lines of data like this:
    // "voltage: 0.73 deg C: 22.75 deg F: 72.96"

    Serial.print("voltage: ");
    Serial.print(voltage);
    Serial.print("  deg C: ");
    Serial.print(degreesC);

Catatan kode:

Serial.begin(115200);

Sebelum menggunakan serial monitor, harus menyertakan Serial.begin() sebagai inisialisasi awal. 115200 adalah "baud rate", atau kecepatan komunikasi data. Ketika dua perangkat atau antara Arduino dengan komputer berkomunikasi satu sama lain, maka harus diseting dengan baud rate yang sama.

Serial.print(degreesC);

Serial.print() merupakan salah satu fungsi yang sering digunakan untuk serial monitor. Perintah ini dapat menampilkan tulisan (string), angka atau data dari hasil pengukuran.

Serial.println(degreesF);

Serial.println() mempunyai fungsi yang sama dengan Serial.print() perbedaanya setelah fungsi ini menampilkan data akan diakhiri dengan akhir baris jadi untuk data yang akan ditampilkan selanjutnya pada garis baru.

Apa yang seharusnya kamu lihat:

Kali ini untuk melihat latihan ini bekerja atau tidak kamu harus menggunakan fitur serial monitor pada software Arduino IDE atau aplikasi Bluino Loader. Untuk membuka serial monitor kamu dapat mengklik ikon kaca pembesar dipojok kanan atas, atau pada aplikasi ini kamu dapat membuaka langsung fitur serial monitor tersebut dengan mengklik ikon yang berada di samping ikon upload.

Kamu dapat membaca suhu setempat yang terukur oleh sensor suhu. Jika tidak menampilkan, pastikan sketch sudah masuk kedalam Arduino dan setingan baud rate pada serial monitor sudah sama 115200.

Contoh yang harus terlihat pada serial monitor:

voltage: 0.73 deg C: 23.24 deg F: 73.84
voltage: 0.73 deg C: 23.24 deg F: 73.84
voltage: 0.73 deg C: 22.75 deg F: 72.96
voltage: 0.73 deg C: 23.24 deg F: 73.84
voltage: 0.73 deg C: 23.24 deg F: 73.84

Read More